/***************************************************
 *                    FPS Boost                    *
 ***************************************************
 * Some people haz sandpz, plz fix                 *
 *                                                 *
 * LAST EDIT: 17.06.2017                           *
 * CHANGES: Fixed messageloop                      *
 * BY: Dizzy                                       *
 ***************************************************/

#include common_scripts\utility;
#include maps\mp\_utility;
#include maps\mp\gametypes\_hud_util;


init()
{
	// precachemodel( "dpad_laser_designator" );
	level thread onPlayerConnect();
}

onPlayerConnect()
{
	for(;;)
	{
		level waittill( "connected", player );		
		
		if( !isDefined( player.message_shown) )
			player.message_shown = 0;
		
		if( !isDefined( player.cur_laser ) )
			player.cur_laser = 0;
		
		player thread watchButton();
		player thread onPlayerSpawned();
	}
}

onPlayerSpawned()
{
	self endon("disconnect");

	for(;;)
	{
		self waittill("spawned_player");
		
		if( !self.message_shown ) {
			self.message_shown = 1;
			self iPrintlnBold( "^7Press ^3[{+actionslot 3}] ^7to toggle ^2laser" );
		}
		
		self setClientDvar("laserForceOn", "0");
		self setClientDvar("laserLight", "0");
		self setClientDvar("cg_laserLight", "0");
		self setClientDvar("laserLightWithoutNightvision", "0");

		// self setWeaponHudIconOverride( "actionslot4", "dpad_laser_designator" );
		// self setWeaponHudIconOverride( "actionslot3", "dpad_laser_designator" );
		// self setWeaponHudIconOverride( "actionslot1", "dpad_laser_designator" );
		
		self SetActionSlot( 1, "nightvision" );
	}
}

watchButton()
{
	self endon("disconnect");
	
	self notifyOnPlayerCommand( "laser_toggle", "+actionslot 3" );
	
	for(;;) {
		self waittill( "laser_toggle" );
		
		self.cur_laser = !self.cur_laser;
		self setClientDvar( "laserForceOn", self.cur_laser );
		
		if( self.cur_laser )
			self iPrintlnBold( "^2Laser ^3On" );
		else 
			self iPrintlnBold( "^2Laser ^3Off" );
	}
	
}